Dim FileName, Find, ReplaceWith, FileContents, dFileContents,bBackup,bBackupExtension,BackupFileName

Find         	= WScript.Arguments(0)
ReplaceWith  	= WScript.Arguments(1)
FileName     	= WScript.Arguments(2)
No_Messages  	= WScript.arguments(3)
bBackup      	= Wscript.arguments(4)
bBackupExtension= Wscript.arguments(5) 

'Read source text file
FileContents = GetFile(FileName)

'replace all string In the source file
dFileContents = replace(FileContents, Find, ReplaceWith, 1, -1, 1)

'Compare source And result
if dFileContents <> FileContents Then
  'Take backup before writing new file, if flag is true
  If bBackup = "True" Then
    BackupFileName = FileName & bBackupExtension
    WriteFile BackupFileName, FileContents
  End If

  'write result If different
  WriteFile FileName, dFileContents

  If No_Messages = "False" Then
	  Wscript.Echo "Replace done."
  	If Len(ReplaceWith) <> Len(Find) Then 'Can we count n of replacements?
   	 Wscript.Echo _
    		( (Len(dFileContents) - Len(FileContents)) / (Len(ReplaceWith)-Len(Find)) ) & _
 	   " replacements."
  	End If
  End If
Else
  If No_messages = False Then
	  Wscript.Echo "Searched string Not In the source file"
  End If
End If

'Read text file
function GetFile(FileName)
  If FileName<>"" Then
    Dim FS, FileStream
    Set FS = CreateObject("Scripting.FileSystemObject")
      on error resume Next
      Set FileStream = FS.OpenTextFile(FileName)
      GetFile = FileStream.ReadAll
  End If
End Function

'Write string As a text file.
function WriteFile(FileName, Contents)
  Dim OutStream, FS

  on error resume Next
  Set FS = CreateObject("Scripting.FileSystemObject")
    Set OutStream = FS.OpenTextFile(FileName, 2, True)
    OutStream.Write Contents
End Function